// A simple program to demonstrate playing around
// with simple objects and simple interactions
// by Brock Craft
// Modified 6 April 2005
//
// Warning: this code ain't elegant - but it works!

RectObject[] r1;
int num = int(10+random(20));  // makes between 10 and 30 objects
PImage b;

void setup()
{
  size(647,400);  //golden ratio - cuz I like it.
  stroke(205);
  colorMode(HSB);
  frameRate(30);
  PFont f = loadFont("hooge_06_66.vlw");
  textFont(f, 10);
  textAlign(LEFT);

  // stuff an array with a bunch of Rectangular objects

  r1 = new RectObject[num];
  for(int i=0; i<num; i++) {
    float x=random(width)-50;
    float y=-200;
    float s=random(200);
    float sp=random(20);
    float col=random(255);
    float a=random(255);
    r1[i] = new RectObject(x,y,s,sp,col,a);
  }

}

// draw the scene

void draw(){
  background(51);

  for(int i=0; i<num; i++) {
    r1[i].draw();
  }

  fill(205);
  text("speed: "+int(r1[0].sp),10,20);
  text("transparency: "+int(r1[0].a),10,40);

  // listen for input

  if (mousePressed==true){
    r1[0].initialize();
  }

  // adjust Alpha

  if(keyPressed) {
    if (key == 'A') {
      for(int i=0; i<num; i++) {
        r1[i].plusAlpha();
      }
    }
    if (key == 'a') {
      for(int i=0; i<num; i++) {
        r1[i].lessAlpha();
      }
    }

    // adjust Speed

    if (key == 'S') {
      for(int i=0; i<num; i++) {
        r1[i].plusSpeed();
      }
    }
    if (key == 's') {
      for(int i=0; i<num; i++) {
        r1[i].lessSpeed();
      }
    }

    // adjust Stroke

    if (key == 'X') {
      stroke(205);
    }

    if (key == 'x') {
      noStroke();
    }

    if (key == '+') {
      for(int i=0; i<num; i++) {
        r1[i].plusSize();
      }
    }
    if (key == '-') {
      for(int i=0; i<num; i++) {
        r1[i].lessSize();
      }
    }
  }

}

// here are the characterists of RectObject objects

class RectObject {

  float x;
  float y;
  float s;
  float sp;
  float col;
  float a;

  RectObject (float xloc, float yloc, float sz, float speed, float colour, float alph){

    x=xloc;
    y=yloc;
    s=sz;
    sp=speed;
    col=colour;
    a=alph;

  }

  // here's how they draw themselves

  void draw (){
    fill(col,100,100,a);
    rect (x, y, s, s);
    if (y < height+10){
      y=y+sp;
    }
    else{
      y=-200; // starts objects over above the top border.
      // should be linked to the object's size, but this
      // is a kludge
    }
  }

  // interaction bits - could have put them in
  // an interaction method but I was lazy

  void plusAlpha(){
    if (a<255){
      a=a+10;
    }
  }
  void lessAlpha(){
    if (a>0){
      a=a-10;
    }
  }
  void plusSpeed(){
    sp=sp+1;
  }
  void lessSpeed(){
    if (sp>0){
      sp=sp-1;
    }
  }
  void plusSize(){
    s=s+10;
  }
  void lessSize(){
    if (s>0){
      s=s-10;
    }
  }

  // this clears the screen and starts over if the mouse is clicked

  void initialize(){
    for(int i=0; i<num; i++) {
      float x=random(width);
      float y=-200;
      float s=random(200);
      float sp=random(20);
      float col=random(255);
      float a=random(255);
      r1[i] = new RectObject (x,y,s,sp,col,a);
    }
  }
}